In QuickTime Vor- und Zurückspringen

Youtube und andere Videoanbieter, ja sogar die Wiedergabe von Videos im Vollbildmodus unter iOS bieten eine Funktion an, mit der man im Video um einen gewissen Betrag vor- oder zurückspringen kann. QuickTime unter macOS hingegen bietet neben dem traditionellen Vor- und Zurückspulen das Springen nicht an.

Jedoch lässt sich QuickTime mit einem AppleScript ansteuern, sodass der Player von der momentanen Abspielposition ausgehend, diese um einen gewissen Betrag erhöht oder reduziert; also quasi springt. Um diesen AppleScript dann auch einer Taste oder Tastenkombination zuzuweisen, muss man ihn in einer Schnellaktion speichern. Das geht im Automator:

Im Automator eine Schnellaktion erstellen.
Im Automator eine Schnellaktion erstellen.

Dann muss ein AppleScript-Block in den Ablauf eingefügt werden und zum Vorspringen der folgende Code eingegeben werden:

property step : 10
tell application "QuickTime Player"
    set playerPosition to (current time of front document) + step
    set movieDuration to duration of front document
    if (playerPosition > movieDuration) then
        if front document is playing then
            stop front document
        end if
        set playerPosition to movieDuration
    end if
    if front document is playing then
        set current time of front document to playerPosition
        play front document
    else
        set current time of front document to playerPosition
    end if
end tell

Mit diesem AppleScript wird um 10 Sekunden vorwärts gesprungen.

Wichtig ist, dass die Schnellaktion keine Eingabe erhält und nur der QuickTime Player das Ziel des AppleScripts ist. Im Ergebnis sollte das dann wie folgt aussehen:

Schnellaktion zum vorwärts Springen.
Schnellaktion zum vorwärts Springen.

Nachdem diese Schnellaktion nun abgespeichert ist, kann derselbe Ablauf für das Zurückspringen durchgeführt werden. Hierfür sollte jedoch der folgende Code benutzt werden:

property step : 5
tell application "QuickTime Player"
    set playerPosition to (current time of front document) - step
    set movieDuration to duration of front document
    if (playerPosition < 0) then
        set playerPosition to 0
    end if
    if front document is playing then
        set current time of front document to playerPosition
        play front document
    else
        set current time of front document to playerPosition
    end if
end tell

Mit diesem AppleScript wird um 5 Sekunden zurück gesprungen.

sodass das Ergebnis wie folgt aussieht:

Schnellaktion zum rückwärts Springen.
Schnellaktion zum rückwärts Springen.

Zu guter Letzt müssen diese Schnellaktionen nun noch einer Taste oder Tastenkombination zugewiesen werden. Dies geschieht in den Systemeinstellungen der Tastatur unter dem Reiter Kurzbefehle. Hier sollten die Schnellaktionen, nachdem sie im Automator erzeugt wurden, unter Allgemein auffindbar sein. Ich habe ihnen die linke und rechte Pfeiltaste zugewiesen, sodass ich im QuickTime Player somit leicht vorwärts und rückwärts springen kann. Das Ergebnis sieht dann wie folgt aus:

Systemeinstellungen der Kurzbefehle.
Systemeinstellungen der Kurzbefehle.

Nun können im QuickTime Player selbst die Schnellaktionen zum Vor- und Zurückspringen durch die linke und rechte Pfeiltaste ausgeführt werden und sie können auch über die Menüleiste per Mausklick ausgeführt werden.

Dienste zum vor- und rückwärts Springen in QuickTime.
Dienste zum vor- und rückwärts Springen in QuickTime.

Um den Betrag, um den gesprungen wird, zu ändern, muss man nun lediglich die Zeile property step : 10 im AppleScript ändern, wobei die angegeben Zahl die zu springenden Sekunden angibt.